francis.wang
4c86c082a2
Combine poky (Yocto scarthgap), meta-openembedded (scarthgap), and meta-openwrt into a single repository. Components: - poky/ Yocto core framework (BitBake + OE-Core) - meta-openembedded/ Community layers (meta-oe, meta-python, meta-networking) - meta-openwrt/ OpenWrt customization layer - setup-env.sh One-click build environment setup - README.md Project documentation
34 lines
1.3 KiB
BlitzBasic
34 lines
1.3 KiB
BlitzBasic
SUMMARY = "Program for providing universal TLS/SSL tunneling service"
|
|
DESCRIPTION = "SSL encryption wrapper between remote client and local (inetd-startable) or remote server."
|
|
HOMEPAGE = "https://www.stunnel.org/"
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING.md;md5=906ac034adaee9d093318e51b53453ca"
|
|
|
|
DEPENDS = "autoconf-archive libnsl2 openssl"
|
|
|
|
SRC_URI = "https://stunnel.org/archive/5.x/${BP}.tar.gz \
|
|
file://fix-openssl-no-des.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "3d532941281ae353319735144e4adb9ae489a10b7e309c58a48157f08f42e949"
|
|
|
|
inherit autotools bash-completion pkgconfig
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6 systemd', d)} libwrap"
|
|
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
PACKAGECONFIG[libwrap] = "--enable-libwrap,--disable-libwrap,tcp-wrappers"
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
|
|
|
|
EXTRA_OECONF += "--with-ssl='${STAGING_EXECPREFIXDIR}' --disable-fips"
|
|
|
|
# When cross compiling, configure defaults to nobody, but provides no option to change it.
|
|
EXTRA_OEMAKE += "DEFAULT_GROUP='nogroup'"
|
|
|
|
# stunnel3 is a Perl wrapper to allow use of the legacy stunnel 3.x commandline
|
|
# syntax with stunnel >= 4.05
|
|
PACKAGES =+ "stunnel3"
|
|
FILES:stunnel3 = "${bindir}/stunnel3"
|
|
RDEPENDS:stunnel3 += "${PN} perl"
|