francis.wang
4c86c082a2
Combine poky (Yocto scarthgap), meta-openembedded (scarthgap), and meta-openwrt into a single repository. Components: - poky/ Yocto core framework (BitBake + OE-Core) - meta-openembedded/ Community layers (meta-oe, meta-python, meta-networking) - meta-openwrt/ OpenWrt customization layer - setup-env.sh One-click build environment setup - README.md Project documentation
60 lines
1.8 KiB
BlitzBasic
60 lines
1.8 KiB
BlitzBasic
SUMMARY = "Tracker is a file search engine"
|
|
LICENSE = "GPL-2.0-only & LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://COPYING.GPL;md5=ee31012bf90e7b8c108c69f197f3e3a4 \
|
|
file://COPYING.LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
|
|
"
|
|
|
|
DEPENDS = " \
|
|
dbus-native \
|
|
python3-pygobject-native \
|
|
glib-2.0 \
|
|
sqlite3 \
|
|
libarchive \
|
|
dbus \
|
|
icu \
|
|
json-glib \
|
|
libsoup-3.0 \
|
|
libstemmer \
|
|
"
|
|
|
|
|
|
inherit gettext gnomebase gobject-introspection vala gtk-doc bash-completion python3native
|
|
|
|
SRC_URI += "file://0001-fix-reproducibility.patch"
|
|
SRC_URI[archive.sha256sum] = "ab3d4a50937e04c5ed7846f6dbb999e2909819402f389ca592ee6b77dd28d1f9"
|
|
|
|
# text search is not an option anymore and requires sqlite3 build with
|
|
# PACKAGECONFIG[fts5] set (default)
|
|
|
|
# set required cross property sqlite3_has_fts5
|
|
do_write_config[vardeps] += "PACKAGECONFIG"
|
|
do_write_config:append() {
|
|
echo "[properties]" > ${WORKDIR}/meson-tracker.cross
|
|
echo "sqlite3_has_fts5 = 'true'" >> ${WORKDIR}/meson-tracker.cross
|
|
}
|
|
|
|
EXTRA_OEMESON = " \
|
|
--cross-file ${WORKDIR}/meson-tracker.cross \
|
|
-Dman=false \
|
|
-Dsystemd_user_services=${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)} \
|
|
-Dsystemd_user_services_dir=${systemd_user_unitdir} \
|
|
-Dsoup=soup3 \
|
|
${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Dvapi=enabled', '-Dvapi=disabled', d)} \
|
|
"
|
|
|
|
do_install:prepend() {
|
|
sed -i -e 's|${B}/../${PN}-${PV}|${TARGET_DBGSRC_DIR}|g' ${B}/src/libtracker-sparql/tracker-sparql-enum-types.c
|
|
sed -i -e 's|${B}/../${PN}-${PV}|${TARGET_DBGSRC_DIR}|g' ${B}/src/libtracker-sparql/core/tracker-data-enum-types.c
|
|
}
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/tracker3 \
|
|
${libdir}/tracker-3.0 \
|
|
${systemd_user_unitdir} \
|
|
"
|