francis.wang
4c86c082a2
Combine poky (Yocto scarthgap), meta-openembedded (scarthgap), and meta-openwrt into a single repository. Components: - poky/ Yocto core framework (BitBake + OE-Core) - meta-openembedded/ Community layers (meta-oe, meta-python, meta-networking) - meta-openwrt/ OpenWrt customization layer - setup-env.sh One-click build environment setup - README.md Project documentation
51 lines
1.5 KiB
BlitzBasic
51 lines
1.5 KiB
BlitzBasic
SUMMARY = "Remote desktop daemon for GNOME using pipewire."
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gettext gsettings features_check useradd
|
|
|
|
REQUIRED_DISTRO_FEATURES = "opengl polkit"
|
|
|
|
SRC_URI[archive.sha256sum] = "97443eaffe4b1a69626886a41d25cbeb2c148d3fed43d92115c1b7d20d5238ab"
|
|
|
|
DEPENDS = " \
|
|
asciidoc-native \
|
|
libdrm \
|
|
libei \
|
|
libepoxy \
|
|
cairo \
|
|
glib-2.0 \
|
|
pipewire \
|
|
polkit \
|
|
libnotify \
|
|
libopus \
|
|
libsecret \
|
|
nv-codec-headers \
|
|
tpm2-tss \
|
|
"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
rdp \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[tests] = "-Dtests=true,-Dtests=false,pipewire-native wireplumber-native dbus-native"
|
|
PACKAGECONFIG[vnc] = "-Dvnc=true,-Dvnc=false,libvncserver"
|
|
PACKAGECONFIG[rdp] = "-Drdp=true,-Drdp=false,freerdp3 fuse3 libxkbcommon"
|
|
PACKAGECONFIG[systemd] = "-Dsystemd=true,-Dsystemd=false,systemd"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --no-create-home --user-group --home-dir ${sysconfdir}/polkit-1 polkitd"
|
|
|
|
do_install:append() {
|
|
if [ -d ${D}${datadir}/polkit-1/rules.d ]; then
|
|
chmod 700 ${D}${datadir}/polkit-1/rules.d
|
|
chown polkitd:root ${D}${datadir}/polkit-1/rules.d
|
|
fi
|
|
}
|
|
|
|
PACKAGE_DEBUG_SPLIT_STYLE = "debug-without-src"
|
|
FILES:${PN} += "${systemd_user_unitdir} ${systemd_system_unitdir} ${datadir} ${libdir}/sysusers.d ${libdir}/tmpfiles.d"
|