francis.wang
4c86c082a2
Combine poky (Yocto scarthgap), meta-openembedded (scarthgap), and meta-openwrt into a single repository. Components: - poky/ Yocto core framework (BitBake + OE-Core) - meta-openembedded/ Community layers (meta-oe, meta-python, meta-networking) - meta-openwrt/ OpenWrt customization layer - setup-env.sh One-click build environment setup - README.md Project documentation
75 lines
3.7 KiB
BlitzBasic
75 lines
3.7 KiB
BlitzBasic
KBRANCH ?= "v6.6/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# CVE exclusions
|
|
include recipes-kernel/linux/cve-exclusion.inc
|
|
include recipes-kernel/linux/cve-exclusion_6.6.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v6.6/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v6.6/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v6.6/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v6.6/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v6.6/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v6.6/standard/base"
|
|
KBRANCH:qemux86 ?= "v6.6/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v6.6/standard/base"
|
|
KBRANCH:qemuloongarch64 ?= "v6.6/standard/base"
|
|
KBRANCH:qemumips64 ?= "v6.6/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "d81ffd8843535762fecf5aa5fb2ca7d2c4343038"
|
|
SRCREV_machine:qemuarm64 ?= "1f7f3a52dacadfcc75863f25252a534b06fdaeeb"
|
|
SRCREV_machine:qemuloongarch64 ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_machine:qemumips ?= "4410226fddf113b89cceb26e7ee5ca5bb70c55fb"
|
|
SRCREV_machine:qemuppc ?= "8f8faf1fe9183f295901f8f2b8916ff54f4a4bfb"
|
|
SRCREV_machine:qemuriscv64 ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_machine:qemuriscv32 ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_machine:qemux86 ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_machine:qemux86-64 ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_machine:qemumips64 ?= "14ca63e9f1ce2090e189c16b1024ed3df8f833f0"
|
|
SRCREV_machine ?= "a8a7d078f151a24e01d4501853c88c6b08c9cad9"
|
|
SRCREV_meta ?= "4a6f16d14b76e28ab7615c88e2fbdf95ee15fc98"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "924b4a879cbb75aef37c160b955b92f6894b11a4"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v6.6/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH};protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.6;destsuffix=${KMETA};protocol=https"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "6.6.142"
|
|
|
|
PV = "${LINUX_VERSION}+git"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32|qemuloongarch64)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc features/nf_tables/nft_test.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc features/gpio/sim.scc", "", d)}"
|
|
# libteam ptests from meta-oe needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/net/team/team.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|