francis.wang
4c86c082a2
Combine poky (Yocto scarthgap), meta-openembedded (scarthgap), and meta-openwrt into a single repository. Components: - poky/ Yocto core framework (BitBake + OE-Core) - meta-openembedded/ Community layers (meta-oe, meta-python, meta-networking) - meta-openwrt/ OpenWrt customization layer - setup-env.sh One-click build environment setup - README.md Project documentation
28 lines
1.2 KiB
BlitzBasic
28 lines
1.2 KiB
BlitzBasic
SUMMARY = "MusicBrainz client library"
|
|
DESCRIPTION = "The MusicBrainz client is a library which can be built into other programs. The library allows you to access the data held on the MusicBrainz server."
|
|
HOMEPAGE = "http://musicbrainz.org"
|
|
LICENSE = "LGPL-2.1-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING.txt;md5=fbc093901857fcd118f065f900982c24"
|
|
DEPENDS = "expat libxml2 libxml2-native neon neon-native libmusicbrainz-native"
|
|
|
|
PV = "5.1.0+git"
|
|
|
|
SRCREV = "4655b571a70d73d41467091f59c518517c956198"
|
|
SRC_URI = "git://github.com/metabrainz/libmusicbrainz.git;branch=master;protocol=https \
|
|
file://0001-http-fetch-Pass-a-non-null-buffer-to-ne_set_request_.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
EXTRA_OECMAKE:append:class-target = " -DIMPORT_EXECUTABLES=${STAGING_LIBDIR_NATIVE}/cmake/${BPN}/ImportExecutables.cmake"
|
|
|
|
do_install:append:class-native() {
|
|
install -Dm 0755 ${B}/src/make-c-interface ${D}${bindir}/make-c-interface
|
|
install -Dm 0644 ${B}/ImportExecutables.cmake ${D}${libdir}/cmake/${BPN}/ImportExecutables.cmake
|
|
sed -i -e s:'${B}'/src/::g ${D}${libdir}/cmake/${BPN}/ImportExecutables.cmake
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|